41- WDT, el Perro Guardian de Arduino

¿Qué es el WDT de Arduino?

Esta lección analiza el dispositivo y el trabajo con el temporizador de vigilancia (Watchdog), para lo cual se propone utilizar la biblioteca GyverWDT, que proporciona un control total sobre el WDT y acceso a todas sus configuraciones y modos de funcionamiento. La biblioteca es muy ligera y se adapta a la mayoría de microcontroladores AVR, es decir, en particular para todas las placas Arduino basadas en ellos.

El temporizador de vigilancia en Arduino es una unidad asíncrona independiente sincronizada desde un generador RC interno separado, cuya frecuencia es de aproximadamente 128 kHz (algo que depende de la temperatura y el voltaje de suministro). Cabe señalar que este generador fue diseñado originalmente como una fuente de reloj de eficiencia energética y no implica una alta precisión, la desviación de frecuencia durante la producción es de aproximadamente el 10%. Si lo desea, este oscilador también puede sincronizar el núcleo AVR, en caso de que no se proporcione un resonador de cristal externo y el oscilador RC interno de 8 MHz no cumpla con los requisitos de consumo de energía.

El temporizador de vigilancia (Watchdog) es un registro de conteo simple de 10 bits que se incrementa en cada borde de la señal de reloj que proviene del divisor. Tan pronto como el valor en este registro de conteo llega a 1023, se produce un tiempo de espera y el temporizador de vigilancia, según el modo establecido, inicia un restablecimiento del microcontrolador o activa una interrupción. Para evitar un tiempo de espera, puede restablecer el temporizador de vigilancia a 0 utilizando la función corta Watchdog.reset () de la biblioteca GyverWDT, o la instrucción del ensamblador «WDR».

¿Por qué necesito un temporizador de vigilancia? Le permite reiniciar automáticamente el microcontrolador en caso de que el programa se cuelgue, lo que puede ser necesario en proyectos independientes. Además, la biblioteca GyverWDT brinda la capacidad de usar el temporizador de vigilancia para otros fines, por ejemplo, para generar interrupciones de alta prioridad sin usar los temporizadores de hardware principales, lo que puede ser muy útil en proyectos complejos, por ejemplo, para sondear regularmente sensores. No olvide que el temporizador de vigilancia permanece activo en todos, incluso en los modos de suspensión más profundos, y puede despertar al microcontrolador con una interrupción. El modo de vigilancia combinado también puede ser útil, para sondear sensores simultáneamente, actuar como un temporizador de vigilancia para un dispositivo externo y monitorear el funcionamiento de su propio kernel.

Divisores de frecuencia de vigilancia

¿Por qué aproximar? Debido a que la frecuencia del temporizador de vigilancia que ya está en producción tiene una distribución decente, y si en valores pequeños del divisor esto prácticamente no aparece (16 ms +/- 1,6 ms), entonces en valores grandes puede convertirse en un problema grave (8 s +/- 1 s) …

No olvide que un oscilador RC, a diferencia de un resonador de cuarzo, tiene una pequeña dependencia de frecuencia de la temperatura y la tensión de alimentación.

Biblioteca GyverWDT.

Para trabajar con Watchdog, puede usar la biblioteca avr incorporada, pero usaremos una biblioteca con un conjunto más amplio de configuraciones: GyverWDT, enlace de descarga aquí.

Funciones de la biblioteca GyverWDT:

• Watchdog.reset(); un comando corto y rápido para restablecer el temporizador de vigilancia a 0, llamado dentro del programa para confirmar el funcionamiento normal.
• Watchdog.disable(); comando corto para detener el temporizador de vigilancia. Llamada para deshabilitar el perro guardián por completo.
• Watchdog.enable(mode, prescaler); función para configurar e iniciar el temporizador (ver ejemplo)

¿Por qué necesita el modo combinado? Permite usar interrupciones y reinicios al mismo tiempo, lo que puede ser muy poderoso. Cómo funciona:

• Si el motivo de la congelación radica en un error de software, por ejemplo, en una espera interminable para que lleguen los datos. El primer tiempo de espera desencadenará una interrupción de alta prioridad si pudiéramos ingresar y comprender que sucedió: saber si el bloqueo es claramente por software, no hardware. En este caso, podemos intentar corregir un error de programa justo dentro de la interrupción o advertir al usuario que el código escrito tiene áreas problemáticas. Si logramos resolver rápidamente el problema antes de que ocurra el próximo tiempo de espera, podemos reconfigurar el temporizador de vigilancia con la función watchdog_enable () para que en el próximo tiempo de espera nos envíe a una interrupción de señalización en lugar de un reset completo. Si no fue posible solucionar rápidamente la causa del congelamiento, el próximo tiempo de espera reiniciará automáticamente el controlador.
• Si es necesario utilizar interrupciones al mismo tiempo (por ejemplo, para sensores de sondeo) y protección contra congelamiento. En la función personalizada, las interrupciones, además de las acciones que necesitemos, sondear sensores, etc. la función de reconfiguración simplemente se agrega con watchdog_enable (), si la reconfiguración no ocurrió, entonces el controlador no ingresó al procedimiento de interrupción, simplemente se colgó. El próximo tiempo de espera reiniciará el controlador.
• Si necesita monitorear el rendimiento del hardware tanto del dispositivo externo como del Arduino. Por ejemplo, cuando microcontrolador y el módulo Bluetooth / Wi-Fi / GSM / GPS funcionan juntos. ¿Cómo implementar esto? Watchdog está configurado para el período requerido. Un dispositivo externo debe enviar periódicamente una confirmación de su operabilidad al microcontrolador, puede ser un pulso generado periódicamente usando el GPIO de un dispositivo externo, iniciando una interrupción externa, o un mensaje enviado por un dispositivo externo a través de uno de los interfaces, y de manera similar iniciando interrupción en el microcontrolador. Dentro de la rutina de interrupción, la función corta se llama watchdog_reset (); reiniciar el temporizador de vigilancia. Si un dispositivo externo se cuelga y deja de enviar datos / pulsos, no se producen reinicios de vigilancia y se produce una interrupción, dentro de la cual podemos restablecer fácilmente el dispositivo externo aplicándole un nivel bajo (se requiere un pull-up externo a VCC). El perro guardián se reconfigura en la misma interrupción. Si el Arduino se cuelga, no reconfigurará el perro guardián a tiempo y el próximo tiempo de espera iniciará un reinicio del microcontrolador.

Ejemplos de programa para WDT Arduino.

WDT como fuente de interrupción

#include "GyverWDT.h"
/ *
   Un ejemplo del uso del perro guardián como generador de interrupciones
   Consulte GyverWDT.h para ver los tiempos de espera frente a los divisores.
* /
void setup() {
  Serial.begin(9600);
  pinMode(13, OUTPUT);
  Watchdog.enable(INTERRUPT_MODE, WDT_PRESCALER_128); // Modo de generación de interrupciones, tiempo de espera ~ 1s
}
void loop() {
 / * Bucle cargado * /
  digitalWrite(13, HIGH);
  delay(5000);
  digitalWrite(13, LOW);
  delay(5000);
}
/*  Interrumcion perro guardián */
ISR(WATCHDOG) {
  Serial.println("Hello from interrupt");
}

Sueño profundo y despierta con WDT

#include "GyverWDT.h"
#include <avr/sleep.h>
/*
   Ejemplo de uso de perro guardián en "alarma"
   Consulte GyverWDT.h para ver los tiempos de espera frente a los divisores.
*/
void setup() {
  pinMode(13, OUTPUT);
  set_sleep_mode(SLEEP_MODE_PWR_DOWN); // Seleccione el modo de suspensión deseado
}
void loop() {
  /* Hacemos parpadear el LED y dormimos durante las pausas */
  digitalWrite(13, HIGH);
  Watchdog.enable(INTERRUPT_MODE, WDT_PRESCALER_128); // Modo de interrupción, tiempo de espera ~ 1
  sleep_enable();                                     // Permitir dormir
  sleep_cpu();                                        //  Ve a dormir
  digitalWrite(13, LOW);
  Watchdog.enable(INTERRUPT_MODE, WDT_PRESCALER_128); //  Modo de interrupción, tiempo de espera ~ 1
  sleep_enable();                                     // Permitir dormir
  sleep_cpu();                                        // Ve a dormir
}
/* Interrumpir perro guardián, en el que nos despertamos */
ISR(WATCHDOG) {
  sleep_disable();     //Deshabilitar el sueño
  Watchdog.disable();  // Apagar perro guardián
}

Modo combinado, interrupción + reinicio

#include "GyverWDT.h"
/*
   Ejemplo de uso de perro guardián en modo combinado
   Puede usarse para alertar en caso de congelación
   El primer tiempo de espera desencadena una interrupción, el segundo un reinicio
   Reconfigure el perro guardián para evitar el reinicio
   Consulte GyverWDT.h para ver los tiempos de espera frente a los divisores.
*/
void setup() {
  Serial.begin(9600);
  Serial.println("Program started");
  Watchdog.enable(INTERRUPT_RESET_MODE, WDT_PRESCALER_128);   // Modo combinado, tiempo de espera ~ 1s
  Serial.println("watchdog enabled");
  while (1);                                                  // Razón de la congelación 
  Serial.println("loop started");                             //  No veremos esto debido a la congelación
}
void loop() {
  /*  el programa no alcanzará este código - cuelgue en la configuración */
  Serial.println("hello");
  delay(500);
}
/* El primer tiempo de espera provoca una interrupción */
ISR(WATCHDOG) {
  // Si el motivo del bloqueo es el software, aquí puede intentar solucionarlo */
  Serial.println("warning!");
   // Si la causa no se puede corregir, el siguiente tiempo de espera provoca un reinicio
   // Watchdog.enable (INTERRUPT_RESET_MODE, WDT_PRESCALER_128); // Si reconfiguras el perro guardián aquí, no habrá reinicio
}

Watchdog y sueño.

1. Configure el Arduino en uno de los modos de suspensión.
2. Permita dormir a Arduino.
3. Establecer el perro guardián en un tiempo de espera específico en el modo de interrupción.
4. Mande a dormir a Arduino.
5. Al despertar, estando en la rutina de interrupción del perro guardián, desactive el sueño.
6. Continuar la ejecución del programa.

Problemas.

El principal problema es que el modo de reinicio automático no funciona en algunas placas Arduino. Por el contrario, cuando funciona bien, solo conduce a un reinicio o bucle de arranque sin fin. ¿Por qué está pasando esto? El hecho es que los controladores de lotes nuevos, en el caso de un reinicio del perro guardián, reconfiguran automáticamente el temporizador del perro guardián durante el período mínimo, es decir, 16 ms sin apagarlo. Para evitar un bootlap, es necesario desactivar el watchdog al iniciar el programa, pero como sabes, en la mayoría de las placas base tenemos un Arduino con un bootloader cableado, cuyo tiempo de ejecución es superior a 16 mS. Esto lleva al hecho de que el controlador ni siquiera tiene tiempo para comenzar a ejecutar el programa principal, ya que va directo al reset, esto ocurre cíclicamente e infinitamente. La única forma de detener este proceso es apagar la placa.

Comprobación del estado del perro guardián.

En los ejemplos, la biblioteca contiene un esquema de prueba del soporte del perro guardián en su placa. Cárguelo en la placa y abra el monitor de puerto. Después de 10 segundos de una pausa configurada para simplificar el parpadeo durante el ciclo de arranque, el tiempo de ejecución del programa en segundos se mostrará en el monitor del puerto serie. Si, cuando se alcanza el tiempo de espera, el programa se reinicia y la cuenta regresiva comienza de nuevo, su placa (cargador de arranque) admite el perro guardián al 100%. Si después del reinicio se detiene la salida de tiempo correcta al monitor de puerto y el LED de la placa comienza a parpadear rápidamente y sin parar, el cargador de arranque de la placa no admite el reinicio del perro guardián. Sube cualquier otro boceto a la pizarra para seguir usando.

Verificación de WDT

#include <GyverWDT.h>
/*
 Un ejemplo de soporte de prueba para todas las funciones de vigilancia en su dispositivo
  > Después de 10 segundos de cuenta atrás, el programa comienza de nuevo -> todas las funciones son compatibles
  > Después de un tiempo de espera, el dispositivo se congela, el LED en D13 comienza a parpadear -> solo se admite INTERRUPT_MODE
  En caso de bootloop, tendrá 10 segundos para flashear el dispositivo después de encender
  Para agregar soporte para todas las funciones de vigilancia, descargue optiboot u opte por no usar el gestor de arranque
*/
void setup() {
  Serial.begin(9600);
  Serial.println("Program started , wait 10 seconds");
  delay(10000);                                          //10 segundos para parpadear en caso de bootloop
  Watchdog.enable(RESET_MODE, WDT_PRESCALER_1024);      //  Modo de reinicio del perro guardián, tiempo de espera ~ 8 s
  Serial.println("watchdog enabled");	                //Imprime el tiempo después de que se encendió el perro guardián en segundos                
  while (1) {                                           //  Bucle sin fin, congelar la emulación   
    if (!(millis() % 1000)) {                               // Cada segundo 
      Serial.println((uint16_t)((millis() / 1000) - 10));   // Imprime el tiempo después de que se encendió el perro guardián en segundos
      delay(10);
    }
  }
}
void loop() {}

¿Qué pasa si el cargador de arranque de mi placa no es compatible con el perro guardián?

Si realmente necesita la funcionalidad completa del temporizador de vigilancia, necesita actualizar el cargador de arranque, para esto necesita un programador que admita microcontroladores AVR u otra placa Arduino + un boceto de ISP de Arduino. Lea más en la lección sobre cómo trabajar con el programador. Sin flashear el cargador de arranque, tiene acceso a interrupciones ordinarias que no usan temporizadores y tienen alta prioridad y, en consecuencia, la capacidad de usar el perro guardián en el modo de alarma del microcontrolador.